Free Clojure course. Sign Up for tracking progress →

Clojure: О полиморфизме

Как уже ранее говорилось, получить полиморфное поведение в Clojure достаточно просто:

; Создадим простой калькулятор с помощью хеш-мапы
(defn calc [first-num second-num operation]
  (let [operations-map {"+" +
                        "-" -
                        "*" *
                        "^" (fn [a b] (int (Math/pow a b)))}]
  ((operations-map operation) first-num second-num)))

(calc 2 3 "+") ; => 5
(calc 2 3 "-") ; => -1
(calc 2 3 "*") ; => 6
(calc 2 3 "^") ; => 8

Однако! В Clojure есть еще несколько механизмов, для достижения такого же эффекта, с помощью defmulti и defmethod. Рассмотрим пример:

; Определим мультиметод
(defmulti greeting
; в методе мы извлекаем из хеш-мапы значение под ключем `language`
  (fn [x] (get x "language")))

; Определим методы для мультиметода, значение,
; которое будет передано в него и будет нашим ключем диспетчеризации
(defmethod greeting "English" [_]
  "Hello!")

(defmethod greeting "Russian" [_]
  "Привет!")

; Создадим хеш-мапы для проверки наших методов
(def en {"id" "1" "language" "English"})
(def ru {"id" "2" "language" "Russian"})

(greeting en)
; => "Hello!"

(greeting ru)
; => "Привет!"

Как было описано выше, для регистрации методов для мультиметода нам необходимо какое-либо значение, по которому мы будем производить диспетчеризацию.

; Попробуем вызвать метод на значении, которое еще не зарегистрировано
(def de {"id" "3" "language" "Hallo"})

(greeting de)
Execution error (IllegalArgumentException) at user/eval2502 (REPL:1).
No method in multimethod 'greeting' for dispatch value: Hallo

При попытке вызвать мультиметод на незарегистрированном значении возникает ошибка, однако с помощью опции :default можно подстраховаться и обработать такую ситуацию.

; Создадим метод по умолчанию, если не найдено подходящего
; Важно, мы передаем в качестве значения символ :default !
(defmethod greeting :default [_]
  "Incorrect language provided!")

(greeting de)
; => "No language provided!"

Важно отметить, что мультиметод может ориентироваться не только на переданное значение, но и тип (то есть класс) передаваемого значения:

; Создаем мультиметод, который производит
; диспетчеризацию по переданному типу (классу)
(defmulti hey class)

(defmethod hey Long [_] "You passed an integer!")

(defmethod hey String [x] (str "You passed a string: " x " !"))

(defmethod hey clojure.lang.PersistentVector [_]
  "You passed a vector!")

(defmethod hey :default [_] "Ooops, unknown value!")

(hey 2)
; => "You passed an integer!"

(hey "my awesome string")
; => "You passed a string: my awesome string !"

(hey [1 2])
; => "You passed a vector!"

(hey {:some "value"})
; => "Ooops, unknown value!"

Instructions

Создайте калькулятор (конечно же с помощью defmulti и defmethod), который поддерживает сложение, вычитание и умножение, порядок передачи аргументов приведен в примерах (помните, чтобы мультиметод сработал, ему необходимо получить значение, по которому будет производиться диспетчеризация. Назовите мультиметод my-calc.

(my-calc ["+" 1 2])
; => 3

(my-calc ["-" 3 1])
; => 2

(my-calc ["*" 3 3])
; => 9
The exercise doesn't pass checking. What to do? 😶

If you've reached a deadlock it's time to ask your question in the «Discussions». How ask a question correctly:

  • Be sure to attach the test output, without it it's almost impossible to figure out what went wrong, even if you show your code. It's complicated for developers to execute code in their heads, but having a mistake before their eyes most probably will be helpful.
In my environment the code works, but not here 🤨

Tests are designed so that they test the solution in different ways and against different data. Often the solution works with one kind of input data but doesn't work with others. Check the «Tests» tab to figure this out, you can find hints at the error output.

My code is different from the teacher's one 🤔

It's fine. 🙆 One task in programming can be solved in many different ways. If your code passed all tests, it complies with the task conditions.

In some rare cases, the solution may be adjusted to the tests, but this can be seen immediately.

I've read the lessons but nothing is clear 🙄

It's hard to make educational materials that will suit everyone. We do our best but there is always something to improve. If you see a material that is not clear to you, describe the problem in “Discussions”. It will be great if you'll write unclear points in the question form. Usually, we need a few days for corrections.

By the way, you can participate in courses improvement. There is a link below to the lessons course code which you can edit right in your browser.

If you got stuck and don't know what to do, you can ask a question in our huge and friendly community